μc/os移植的條件

uCOS II的移植需要滿足以下要求： 

　　1）處理器的C編譯器可以產(chǎn)生可重入代碼：可以使用C調(diào)用進入和退出Critical Code（臨界區(qū)代碼）； 

　　2）處理器必須支持硬件中斷，并且需要一個定時中斷源； 

　　3）處理器需能容納一定數(shù)據(jù)的硬件堆棧； 

　　4）處理器需有能在CPU寄存器與內(nèi)存和堆棧交換數(shù)據(jù)的指令。

移植需要完成的工作

CPU的接口部分（Ports）–需要移植的代碼部分 

匯編文件（OS_CPU_A.ASM）、處理器相關(guān)C文件（OS_CPU.H、OS_CPU_C.C)中相關(guān)函數(shù)和變量的聲明定義

OS_CPU_A.ASM文件改寫

OSStartHighRdy()　　　　//OS啟動時調(diào)用,加載用戶最高優(yōu)先級的任務(wù) 

OSCtxSw()　　　　　　　//任務(wù)級調(diào)度 

OSIntCtxSw()　　　　　　//中斷級調(diào)度 

OSTickISR()　　　　　　　//時鐘中斷響應(yīng),將檢測到延時結(jié)束的任務(wù)加入就緒隊列,

    .cdecls C, LIST, "msp430.h"

;用戶鉤子,對應(yīng)os_cpu_c.c中的HOOK函數(shù)

    .ref     OSIntExit

    .ref     OSIntNesting

    .ref     OSISRStkPtr

    .ref     OSPrioCur

    .ref     OSPrioHighRdy

    .ref     OSRunning

    .ref     OSTCBCur

    .ref     OSTCBHighRdy

    .ref     OSTaskSwHook

    .ref     OSTimeTick

;全局量

    .global  OSCtxSw

    .global  OSCPURestoreSR

    .global  OSCPUSaveSR

    .global  OSIntCtxSw

    .global  OSStartHighRdy

    .global  OSTickISR

;中斷使能操作之前保存SR,恢復(fù)中斷使能時CPU狀態(tài)不變

    .asmfunc            ;保存SR寄存器

OSCPUSaveSR:

    MOV.W       SR, R12

    DINT

    NOP

    RETA

    .endasmfunc

    .asmfunc            ;恢復(fù)SR寄存器,保持CPU狀態(tài)

OSCPURestoreSR:

    MOV.W       R12, SR

    NOP

    RETA

    .endasmfunc

    .asmfunc

;OS初始化后,準備運行時調(diào)用

;準備運行的最高優(yōu)先級的任務(wù)。任務(wù)就緒表第一個

;被OSStart()調(diào)用

OSStartHighRdy:

    CALLA       #OSTaskSwHook

    MOV.B       #1, &OSRunning          ; 內(nèi)核運行標(biāo)志

    MOVX.A      SP, &OSISRStkPtr        ; 保存中斷堆棧,系統(tǒng)堆棧

    MOVX.A      &OSTCBHighRdy, R13      ; 將最高優(yōu)先級任務(wù)準備

    MOVX.A      @R13, SP                ;將SP指向OSTCBHighRdy,即任務(wù)堆棧

    POPM.A      #12, R15

    RETI                                ; 模擬中斷,中斷退出應(yīng)執(zhí)行的內(nèi)容在OSISRStkPtr中

    .endasmfunc

    .asmfunc

;任務(wù)級上下文切換

OSCtxSw:

    POP.W       R12                     ;CALLA調(diào)用,當(dāng)前PC地址被壓入系統(tǒng)棧

    POP.W       R13                     ;這里使用的是擴展內(nèi)存地址,地址長度為20位

    PUSH.W      R12                     ;因此壓棧的寫法有變化

    RLAM.A      #4, R13                 

    RLAM.A      #4, R13

    RLAM.A      #4, R13

    MOVX.W      SR,  R12

    ADDX.A      R13, R12

    PUSH.W      R12                     ;保存PC和SR

    PUSHM.A     #12, R15                ; 保存上一個任務(wù)的上下文到它的任務(wù)堆棧

    MOVX.A      &OSTCBCur, R13          ;任務(wù)堆棧構(gòu)建完成

    MOVX.A      SP, 0(R13)              ;前一個任務(wù)的上下文保存

    CALLA       #OSTaskSwHook           ;用戶鉤子

    MOV.B       &OSPrioHighRdy, R13     ;切換任務(wù)

    MOV.B       R13, &OSPrioCur

    MOVX.A      &OSTCBHighRdy, R13      ;

    MOVX.A      R13, &OSTCBCur

    MOVX.A      @R13, SP                ; 堆棧寄存器指向任務(wù)堆棧

    POPM.A      #12, R15                ; 從任務(wù)PCB中恢復(fù)寄存器內(nèi)容,程序開始執(zhí)行

    RETI                                ; 從中斷返回

    .endasmfunc

;OSIntCtxSw()是唯一一個與編譯器相關(guān)的函數(shù)，也是用戶問的最多的。

;中斷級上下文切換

;在此之前必須已經(jīng)對上下文內(nèi)容進行了保存

;由于中斷已經(jīng)發(fā)生，此處不需要再保存CPU寄存器

;OSIntCtxSw()需要調(diào)整堆棧指針，去掉堆棧中一些不需要的內(nèi)容，以使堆棧中只包含任務(wù)的運行環(huán)境

    .asmfunc

OSIntCtxSw:

    CALLA       #OSTaskSwHook

    MOV.B       &OSPrioHighRdy, R13

    MOV.B       R13, &OSPrioCur

    MOVX.A      &OSTCBHighRdy, R13

    MOVX.A      R13, &OSTCBCur

    MOVX.A      @R13, SP                ; 堆棧寄存器指向任務(wù)PCB

    POPM.A      #12, R15                ;從任務(wù)PCB中恢復(fù)寄存器內(nèi)容,程序開始執(zhí)行

    RETI                                ; 中斷返回

    .endasmfunc

;中斷服務(wù)程序中會執(zhí)行OSTimeTick()

;每進行一次中斷，OSTimeTick()都會遍歷所有掛起任務(wù)然后對有延時的任務(wù)控制塊TCB中的OSTCBDly減1

;這樣，當(dāng)延時減為0時，就會把減為0的任務(wù)在就緒表中進行注冊登記。

    .sect  ".text:_isr"                 ; 這個函數(shù)在中斷向量空間

    .asmfunc

;

OSTickISR:                              ;看門狗時鐘中斷

    PUSHM.A     #12, R15                ;保存寄存器內(nèi)容

    BIC.W       #0x01, &SFRIE1          ;禁止看門狗中斷

    CMP.B       #0, &OSIntNesting       ;無中斷嵌套,跳轉(zhuǎn)

    JNE         OSTickISR1              ;跳轉(zhuǎn)到下面的模塊

    MOVX.A      &OSTCBCur, R13          ;保存任務(wù)堆棧

    MOVX.A      SP, 0(R13)

    MOVX.A      &OSISRStkPtr, SP        ;加載中斷堆棧

;只有當(dāng)中斷全部執(zhí)行完畢,

OSTickISR1:

    INC.B       &OSIntNesting           ;產(chǎn)生了一個時鐘中斷

    BIS.W       #0x01, &SFRIE1          ; 禁止看門狗

    NOP

    EINT                                ; 允許中斷嵌套

    NOP

    CALLA       #OSTimeTick             ; 調(diào)用節(jié)拍處理函數(shù)

    DINT                                ; 一般禁用中斷之前調(diào)用OSIntExit()

    NOP

    CALLA       #OSIntExit              ;退出中斷

    CMP.B       #0, &OSIntNesting       ;中斷無嵌套時,跳轉(zhuǎn)

    JNE         OSTickISR2

    MOVX.A      &OSTCBHighRdy, R13      ;恢復(fù)任務(wù)堆棧寄存器

    MOVX.A      @R13, SP

OSTickISR2:

    POPM.A      #12, R15

    RETI                                ; 從中斷中返回

    .endasmfunc

    .sect   WDT_VECTOR

    .short  OSTickISR                   ; 中斷向量,看門狗定時器模式

    .end

OS_CPU_A.ASM中與MSP430硬件機制相關(guān)的部分

1.MSP430單片機有R0~R15十六個通用寄存器，其中PC占用R0，SP占用R1，SR占用R3，因此，切換任務(wù)時有16個寄存器值需要保存。

2.MSP430開關(guān)中斷

_EINT開總中斷 

DINT關(guān)總中斷

3.中斷處理流程

任何當(dāng)前執(zhí)行的指令完成。

指向下一條指令的PC 被壓入堆棧。

SR 被壓入堆棧。

如果在最后一個指令執(zhí)行期間由多個中斷出現(xiàn)，那么具有最高優(yōu)先級的中斷被選中并等待被處理。

在單一源標(biāo)志上，中斷請求標(biāo)志自動復(fù)位。對于軟件處理，多個源標(biāo)志保持被設(shè)定。

SR 被清除。這將終止任何低功耗模式。由于GIE 位被清除，之后的中斷被禁用。

中斷矢量的內(nèi)容被載入到PC：程序繼續(xù)在中斷處理例程所處的地址上執(zhí)行。

4.中斷處理程序由以下指令終止：

RETI（從中斷處理例程返回）

5.時鐘中斷源時鐘的選擇

在這里使用的是看門狗時鐘那么相應(yīng)的也要打開看門時鐘的中斷,但是不要錯誤的把看門狗設(shè)置成安全模式,這樣會造成系統(tǒng)反復(fù)重啟

6.MSP430為16位單片機,堆棧是向下生長

os_cpu_c.c文件的改寫

μC/OS-II 的移植需要用戶改寫OS_CPU_C.C中的六個函數(shù)： 

OSTaskStkInit() 

OSTaskCreateHook() 

OSTaskDelHook() 

OSTaskSwHook() 

OSTaskStatHook() 

OSTimeTickHook() 

實際需要修改的只有OSTaskStkInit()函數(shù)，其他五個函數(shù)需要聲明，但不一定有實際內(nèi)容。這五個函數(shù)都是用戶定義的對操作系統(tǒng)功能的擴展 

其他的鉤子函數(shù)已經(jīng)嵌入到系統(tǒng),會在操作系統(tǒng)執(zhí)行某些操作時被調(diào)用,可以通過os_cfg.h來配置讓系統(tǒng)不使用這些鉤子

/*

 * os_cpu.c

 *

 *  Created on: 2016年11月20日

 *      Author: Tom

 */

#define  OS_CPU_GLOBALS

#include "ucos_ii.h"

#if OS_CPU_HOOKS_EN > 0 && OS_VERSION > 203

void  OSInitHookBegin (void)    //進入OSInit()函數(shù)后，OSInitHookBegin就會被調(diào)用

{

}

#endif

#if OS_CPU_HOOKS_EN > 0 && OS_VERSION > 203

void  OSInitHookEnd (void)      //:OSInitHookEnd與OSInitHookBegin相似，

{

}

#endif

#if OS_CPU_HOOKS_EN > 0

void  OSTaskCreateHook (OS_TCB *ptcb)   //OS_TCBInit會調(diào)用OSTaskCreateHook

{

    ptcb = ptcb;                       /* 防止編譯警告                                         */

}

#endif

#if OS_CPU_HOOKS_EN > 0

void  OSTaskDelHook (OS_TCB *ptcb)  //OSTaskDel()會調(diào)用OSTaskDelHook(ptcb)

{

    ptcb = ptcb;                       /* 防止編譯警告                                     */